@echo off
:: ************************************************************
:: *** Dynalivery Debug Collection Utility                  ***
:: ***   v0.02 beta                                         ***
:: ***                                                      ***
:: *** Modification History                                 ***
:: *** --------------------                                 ***
:: ***  v0.01beta - Sep 6, 2001 (gsb)                       ***
:: ***    -- initial version                                ***
:: ***  v0.02beta - Sep 6, 2001 (gsb)                       ***
:: ***    -- added filename vars                            ***
:: ***                                                      ***
:: *** ---------------------------------------------------- ***
:: *** This script will collect information useful          ***
:: *** to the Dynalivery Technical Support Department in    ***
:: *** debugging Parallel Crystal communication problems.   ***
:: *** This script should be run on a Windows NT client     ***
:: *** attempting to connect to a Parallel Crystal server.  ***
:: ***                                                      ***
:: *** Questions/Comments: TechSupp@dynalivery.com          ***
:: ***                                                      ***
:: *** Syntax:                                              ***
:: ***   DCG.BAT "server"                                   ***
:: ***                                                      ***
:: *** Where "server" is the servername or ip address of    ***
:: *** the parallel crystal report server.                  ***
:: ***                                                      ***
:: ************************************************************

::  some filenames to use in this script...
set OUTFN="results.txt"
set TEMPFN="temp.txt"

:start
if "%1" == "" goto noserver
set SERVERNAME=%1

echo ************************************************************  > %OUTFN%
echo *** Dynalivery Debug Collection Utility                  *** >> %OUTFN%
echo *** ---------------------------------------------------- *** >> %OUTFN%
echo. >> %OUTFN%

:datetime
echo ************************************************************ >> %OUTFN%
echo *** Date/Time of collection                              *** >> %OUTFN%
echo ************************************************************ >> %OUTFN%
echo.|date|find /i "current" >> %OUTFN%
echo.|time|find /i "current" >> %OUTFN%
echo. >> %OUTFN%

:env
echo Collecting environment variables...
echo ************************************************************ >> %OUTFN%
echo *** Environment variables on Client Machine              *** >> %OUTFN%
echo ************************************************************ >> %OUTFN%
set   >> %OUTFN%
echo. >> %OUTFN%

:regdata
echo Collecting registry data...
echo ************************************************************ >> %OUTFN%
echo *** Registry data on Client Machine                      *** >> %OUTFN%
echo ************************************************************ >> %OUTFN%
echo ------------------------------------------------------------ >> %OUTFN%
echo --- Registry data for PCRE 2.4 (and lower) machines      --- >> %OUTFN%
echo ------------------------------------------------------------ >> %OUTFN%
regedit /e %TEMPFN% "HKEY_LOCAL_MACHINE\Software\Mobile Application Servers Inc"
if not exist %TEMPFN% goto no24
type %TEMPFN% >> %OUTFN%
del  %TEMPFN%
goto end24
:no24
echo (empty) >> %OUTFN%
:end24

echo ------------------------------------------------------------ >> %OUTFN%
echo --- Registry data for PCRE 2.5 (and higher) machines     --- >> %OUTFN%
echo ------------------------------------------------------------ >> %OUTFN%
regedit /e %TEMPFN% HKEY_LOCAL_MACHINE\Software\Dynalivery
if not exist %TEMPFN% goto no25
type %TEMPFN% >> %OUTFN%
del %TEMPFN%
goto end25
:no25
echo (empty) >> %OUTFN%
:end25
echo. >> %OUTFN%

:ipconfig
echo Collecting TCP/IP configuration data...
echo ************************************************************ >> %OUTFN%
echo *** TCP/IP Configuration of Client Machine               *** >> %OUTFN%
echo ************************************************************ >> %OUTFN%
ipconfig /all >> %OUTFN%
echo. >> %OUTFN%

:route
echo Collecting TCP/IP routing information...
echo ************************************************************ >> %OUTFN%
echo *** TCP/IP Routing information on Client Machine         *** >> %OUTFN%
echo ************************************************************ >> %OUTFN%
route print >> %OUTFN%
echo. >> %OUTFN%

:nbt_client
echo Collecting NetBIOS table for client...
echo. >> %OUTFN%
echo ************************************************************ >> %OUTFN%
echo *** NetBIOS table on Client Machine                      *** >> %OUTFN%
echo ************************************************************ >> %OUTFN%
nbtstat -n >> %OUTFN%

:ping
echo Pinging the server...
echo ************************************************************ >> %OUTFN%
echo *** Ping the server                                      *** >> %OUTFN%
echo ************************************************************ >> %OUTFN%
ping %SERVERNAME% >> %OUTFN%

:nbt_server
echo Collecting NetBIOS table for server...
echo. >> %OUTFN%
echo ************************************************************ >> %OUTFN%
echo *** NetBIOS table on server                              *** >> %OUTFN%
echo ************************************************************ >> %OUTFN%
nbtstat -a %SERVERNAME% >> %OUTFN%

:nslookup
echo Testing DNS resolution...
echo. >> %OUTFN%
echo ************************************************************ >> %OUTFN%
echo *** Check the DNS server settings                        *** >> %OUTFN%
echo ************************************************************ >> %OUTFN%
nslookup %SERVERNAME% >> %OUTFN% 2> %TEMPFN%
if exist %TEMPFN% type %TEMPFN% >> %OUTFN%
if exist %TEMPFN% del %TEMPFN%

:tracert
echo Tracing route to server...
echo ************************************************************ >> %OUTFN%
echo *** Trace the route to the server                        *** >> %OUTFN%
echo ************************************************************ >> %OUTFN%
tracert %SERVERNAME% >> %OUTFN%


:done
echo.
echo.
echo Done!
echo Please email the %OUTFN% file to Dynalivery Technical Support
echo at the email address: TechSupp@dynalivery.com
echo.
echo Thanks...
goto end

:noserver
echo No server name supplied!
echo.
goto usage

:usage
echo Usage:
echo   dcg.bat "server"
echo.
echo   where "server" is the Parallel Crystal Server

:end